ASP 3.0을 사용해본지 몇년만에 간단한 출력문 코딩하는데,

어색함을 느껴본다...

아래 샘플 코드는 ASP3.0으로 가장 최근에 로그인한 사용자 리스트를 출력하는 코드이다.

<%
''' <summary>
''' 가장 최근에 로그인한 사용자 리스트 출력
''' </summary>
%>
<%
'[1] 변수 선언
Dim objCon: Dim objRs: Dim strSql

'[2] 인스턴스 생성
Set objCon = Server.CreateObject("ADODB.Connection")

'[3] 오픈
objCon.Open(Application("CONNECTION_STRING"))

'[4] 레코드셋 객체의 인스턴스 생성
Set objRs = Server.CreateObject("ADODB.RecordSet")

'[5] 명령어 실행
strSql = "Select Top 7 UserID, LoginIP, LoginDate From MemberLogin Order By Num Desc"
objRs.Open strSql, objCon

'[6] 출력
If objRs.BOF Or objRs.EOF Then
     Response.Write("<center>처음 로그인하셨습니다.</center>")
Else
     Call ShowRecordSet(objRs)
End If

'[7] Close()
objRs.Close(): objCon.Close()

'[8] Nothing
Set objRs = Nothing: Set objCon = Nothing
%>

<%
Sub ShowRecordSet(objRs)
%>
    <h3>최근 로그인 사용자</h3>
    <div style="text-align:left;">
        <ol>
<%
     While Not objRs.EOF
%>
            <li>
              <%= Left(objRs("UserID"), 3) %>... (<%= Left(objRs("LoginIP"), 8) %>XXX)
              <br />
              &nbsp;&nbsp;<i><%=Mid(objRs("LoginDate"), 6)%></i>
            </li>
<%
          objRs.MoveNext()
     WEnd
%>
        </ol>
    </div>
<%
End Sub
%>

끝.